I didn’t do a regular upgrade, and even then I don’t really remember how long it took last time,¹ so I have no idea if it installed any faster. DiskWarrior seemed to be getting lost scanning my hard drive, so I did the format, install, restore dance. The installer’s install/restore mode didn’t seem to be working either, did those two separately.² My free-space story seems much like Erwin’s, with an additional uncertainty point thrown in for good measure — Migration Assistant copied over my old /Developer directory (with a new name), so I had two copies of the developer tools installed for a while.

All that being said, here are a few things that I’ve noticed:

Pros

• Mail seems a lot faster.
• All of my Dashboard widgets survived.
• Mercifully, iPhone developers no longer have to download the entire developer tools package every time they want a new iPhone OS SDK.³

Cons

• None of my Menu Extras survived.
• Imagine, for a moment, that you had put Script Editor in its own Library (Window Menu → Library) under Leopard or other cats prior. You might have thought that you would now have an AppleScript Editor reference in there. You’d have been wrong. Instead, you’d now have a grayed-out, iconless reference to Script Editor.
• My nearby PC is still just as confused when I use “`” inside the window switcher⁴ as it was before I upgraded my Mac to Snow Leopard.

I was wondering what would happen if you could create a new window without activating the app, so I typed this into Script Editor:

tell application "iTerm"
set term to (make new terminal)
tell term
    launch session "default session"
    activate
end tell
end tell

{: lang=applescript }

The result is a brand new iTerm window in my current space, without regard to whether there might already be such a window in another space. Switching spaces from a script is pretty easy too — as long as you aren’t holding down any modifiers when the script runs (say, by having used command-r in Script Editor):

tell application "System Events"
    delay 1 -- so I can let go of command
    keystroke "2" using control down
    delay 1 -- so you can see one switch happen and then the other
    key code 125 using control down
end tell

{: lang=applescript }

The one missing piece is moving a window — I don’t think it’s possible to drag an object via GUI scripting, so you can’t grab the title bar of a window, switch spaces, and then release it. At least it might be possible to create a fairly complex setup from a login script…if you had a lot of time on your hands.

There’s compiled versions of these scripts at the end of the post. They’re saved as run-only application bundles, they have the icons linked above set on them so they look all Leopard-ish, and they have LSUIElement set on them so they don’t pop up in your Dock briefly when you use them.

-- iTerm Here
-- changes inspired by
--     http://henrik.nyh.se/2007/10/open-terminal-here-and-glob-select-in-leopard-finder

on run
-- I was run normally
tell application "Finder"
    if selection is {} then
        set selectedItems to {front window's folder}
    else
        set selectedItems to selection -- as alias list
    end if
end tell
process(selectedItems)
end run

on open (theseItems)
-- Something was dropped on me
process(theseItems)
end open

on process(theseItems)
repeat with thisItem in theseItems
    tell application "iTerm"
        activate
        try
            set term to front terminal
        on error
            set term to (make new terminal)
        end try
        tell term
            set thePath to POSIX path of (thisItem as string)
            repeat until thePath ends with "/"
                set thePath to text 1 thru -2 of thePath
            end repeat
            launch session "default session"
            tell current session
                write text "cd " & quoted form of thePath
            end tell
        end tell
    end tell
end repeat
end process

{: lang=applescript }

-- TextMate Here
-- changes inspired by
--     http://henrik.nyh.se/2007/10/open-in-textmate-from-leopard-finder

on run
-- I was run normally
tell application "Finder"
    if selection is {} then
        set selectedItems to {front window's folder}
    else
        set selectedItems to selection
    end if
end tell
process(selectedItems)
end run

on open (theseItems)
-- Something was dropped on me
process(theseItems)
end open

on process(theseItems)
set theCommand to POSIX path of (path to resource "mate" in bundle (path to application "TextMate"))
repeat with thisItem in theseItems
    set thePath to POSIX path of (thisItem as string)
    set theCommand to theCommand & " " & quoted form of thePath
end repeat
do shell script theCommand
end process

{: lang=applescript }

TextMate Here.app.zip • iTerm Here.app.zip

tell application "Mail" to activate
tell application "System Events"
tell process "Mail"
    -- Run the regular "Reply" command
    tell menu bar 1
        click menu bar item "Message"'s menu "Message"'s menu item "Reply"
    end tell
    delay 1.0 -- Give it a chance to finish

    -- Remember what signature was selected and switch to "None"
    set blib to value of (pop up button 1 of window 1)
    if blib is not "None" then
        click pop up button 1 of window 1 -- The Signature popup
        click menu item "None" of menu 1 of pop up button 1 of window 1
        delay 0.2
    end if

    -- Delete the return Mail inserted; recreate it at the bottom where it belongs
    key code 117 -- Forward delete
    key code 125 using command down -- Command-down (skip to the end)
    key code 36 -- Return

    -- Restore the previously selected Signature
    if blib is not "None" then
        click pop up button 1 of window 1 -- Still the Signature popup
        click menu item blib of menu 1 of pop up button 1 of window 1
        delay 0.2
        key code 117 -- Mail inserts a bonus line here too
    end if
end tell
end tell

{: lang=applescript }

One drawback that I maintain from John’s original is the use of a time delay — I have other scripts that use them, and for each of them I occasionally have the script fail because my machine is a little busier that day.¹ That being said, this script usually runs correctly.

My improvement is how I deal with arbitrary signatures. If you pick a different signature (or no signature) from the popup menu in the compose window, Mail updates the message correctly — so I just use that behavior to do the messy bits.

That was actually the first post in a series (of two). This one opens a new TextMate window on the selected item (if there’s a single item selected), or the current folder otherwise. This makes the script a lot shorter (that and there being a simple command-line TextMate launcher that I can use).

The instructions are the same as last time; save it as an application somewhere you can find it, and call it “TextMate Here”. Find it with the Finder, copy and paste TextMate’s icon onto it, and drag it up into your Finder toolbar.

If you have TextMate installed someplace strange (or have an old enough one that it doesn’t have the mate command in it) it will break; if this happens, you get to keep both pieces.

Here’s the script:

on currentFolder()
    tell application "Finder"
        try
            return POSIX path of (front window's folder as text)
        on error
            return null
        end try
    end tell
end currentFolder

on selectedItem()
    tell application "Finder"
        try
            get the selection
            return POSIX path of (the result's first item as text)
        end try
    end tell
    return currentFolder()
end selectedItem

do shell script "/Applications/TextMate.app/Contents/Resources/mate '" & selectedItem() & "'"

{: lang=applescript }

Feedback, improvements, etc. still welcome.

This is, for lack of a better description, my version of the Open a Command Window Here Windows XP PowerToy. I’ve played around with doing this from the context menu, but I eventually decided I’m not fond of that approach. Since I have the toolbar visible in Finder, however, it’s pretty easy to put a script up there and pretend it’s a real toolbar button.

To use it, save it as an application somewhere you can find it, and call it “Term Here”. Find it with the Finder, copy and paste iTerm’s icon onto it, and drag it up into your Finder toolbar (like how you would drag it into the dock).

My version of this will use the path of the selected item in the front finder window if it is a folder (and is the only thing selected). Otherwise, it will use the path of the Finder window itself. If you want to skip the selection business altogether, just replace the call to selectedFolder() before the last (iTerm) stanza to currentFolder(). It then launches iTerm if needed, create’s a new (empty) window if needed, opens a new tab in that window pushd‘s to the directory, and lists its contents for you.

Here’s the script:

on currentFolder()
tell application "Finder"
    try
        return POSIX path of (front window's folder as text)
    on error
        return null
    end try
end tell
end currentFolder

on selectedFolder()
try
    tell application "Finder"
        get the selection
        set theItem to result's first item as alias
    end tell
    set theInfo to info for theItem
    if theInfo's folder then
        return POSIX path of theItem
    end if
end try
return currentFolder()
end selectedFolder

set targetPath to selectedFolder()
tell application "iTerm"
activate
try
    set term to the front terminal
on error
    set term to (make new terminal)
end try
tell term
    launch session "default session"
    tell current session
        write text "pushd '" & targetPath & "'"
        write text "ls"
    end tell
end tell
end tell

{: lang=applescript }

Feedback, improvements, etc. welcome. Unless you think it should automatically detect whether iTerm or Terminal is your default terminal program, in which case your feedback is only welcome if you can explain a way to detect this from AppleScript that doesn’t double the length of the script. I just don’t care enough about this issue to figure out how to do it.

Spurred on by these hints, I finally got around to do something about it. I created a folder, ~/Library/Login Items/, dropped aliases to applications formerly in my (very lengthy) list of regular login items, and removed them from the OS’s list. Then I saved the following script as Slow Launch.app in that same directory:

-- Delay before the first launch and between subsequent launches
set firstLaunchDelay to 10
set interLaunchDelay to 5

tell application "Finder"
-- Find my list of launch items
set loginItemsFolder to (container of (path to me) as alias)
set loginItemsList to loginItemsFolder's items whose kind is "Alias"

-- Set the initial delay
set launchDelay to firstLaunchDelay

-- Process the list
repeat with loginItem in loginItemsList
    -- Hurry up and wait
    delay launchDelay
    set launchDelay to interLaunchDelay

    -- Open the item; hide it if requested
    open loginItem
    if (loginItem's comment is "hide") then
        delay launchDelay
        set launchDelay to 0
        set (process ( (loginItem's displayed name) as text) )'s visible to false
    end if
end repeat
end tell

{: lang=applescript }

Add Slow Launch.app to the OS’s login items list, and I’m done. I could swear that it even takes less time to launch everything, in spite of all the waiting the script does. The only drawback is that not everything can taken out of the OS’s list; some apps¹ helpfully put themselves back again if you take them off the list, and others² nag you about not being in that list whenever they’re launched. All that being said, it still feels a lot snappier this way.

function setgeometry
{
    local rows=`expr "$1" : '[0-9]*x([0-9]*)$'`
    local cols=`expr "$1" : '([0-9]*)x[0-9]*$'`
    case $TERM in
        Apple_Terminal)
            window=`osascript -e 'tell app "Terminal" to get first window'`
            #echo $window
            osascript -e 'tell app "Terminal"'
                             -e "set number of rows of $window to $rows"
                             -e "set number of columns of $window to $cols"
                         -e 'end tell'
            return $?
            ;;
        *)
            echo "Sorry, I don't know how to do that in $TERM"
            return 1
            ;;
    esac
}

{: lang=bash }

It doesn’t seem to work anymore, but the concept is still valid (i.e., osascript -e 'tell app "Terminal"' -e 'set blib to first window' -e "get blib's number of columns" -e 'end tell' will actually tell you something, although that’s hardly a useful example).

This very website is driven by a CMS, and I have a plugin installed that adds some source code formatting features. This plugin, unsurprisingly, doesn’t know much about AppleScript¹ — so I added a really simple one myself. On my PowerBook, it worked perfectly — on the public webserver, it didn’t.

The reason why turned out to be fairly simple, but it was one of those “simple problems” that you can only find the next day and several meals later. The code formatting package the plugin is based on is a perl translation of an existing PHP package, but most of the syntax definitions haven’t been translated along with it yet.² What’s more, of the small number of definitions present, half of them map to lousy search keywords.

That’s the thing — there are only about 6, one of them is the language the CMS is implemented in, another is a word that gets used in comments a lot, a third gets abbreviated to AS. Getting the picture?

So, to make a long story infinitesimally shorter, I picked one of the remaining definitions to find all the right places that my new syntax had to be registered in order to get used. By some strange coincidence, the C# binding (a.k.a., “csharp”), which I used as an example, was the newest of the lot, and itself wasn’t registered in all the right places, given the way I use everything.

So, by copying the registration details from one non-functional syntax, as if by magic, my new syntax was also non-functional. Yay!

Someday soon, when I’m feeling less cynical, there will be another Cookbook entry on this, with more technical details, probably including my lame syntax definition, and connected to the upstream source so this all gets fixed.

• When multiple lines are selected, they don’t stay that way
• Errors get thrown in end-of-document cases

Beyond that, you’re on your own.

on menuselect(menuName, itemName)
    return false
end menuselect

on postmenuselect(menuName, itemName)
    tell application "BBEdit"
        tell text window 1
            select insertion point before last character of selection
        end tell
    end tell
end postmenuselect

{: lang=applescript }